From 3cb950f2811012aea7937d3d5cb02c0e5f9161fb Mon Sep 17 00:00:00 2001
From: Jim Ray <jimiray@gmail.com>
Date: Thu, 27 Oct 2016 06:36:36 -0600
Subject: [PATCH] copy bundler from oh-my-zsh

---
 modules/bundler/README.md |  50 +++++++++++++++++
 modules/bundler/_bundler  | 104 +++++++++++++++++++++++++++++++++++
 modules/bundler/init.zsh  | 112 ++++++++++++++++++++++++++++++++++++++
 3 files changed, 266 insertions(+)
 create mode 100644 modules/bundler/README.md
 create mode 100644 modules/bundler/_bundler
 create mode 100644 modules/bundler/init.zsh

diff --git a/modules/bundler/README.md b/modules/bundler/README.md
new file mode 100644
index 00000000..04d55144
--- /dev/null
+++ b/modules/bundler/README.md
@@ -0,0 +1,50 @@
+# Bundler
+
+- adds completion for basic bundler commands
+- adds short aliases for common bundler commands
+  - `be` aliased to `bundle exec`
+  - `bl` aliased to `bundle list`
+  - `bp` aliased to `bundle package`
+  - `bo` aliased to `bundle open`
+  - `bout` aliased to `bundle outdated`
+  - `bu` aliased to `bundle update`
+  - `bi` aliased to `bundle install --jobs=<cpu core count>` (only for bundler `>= 1.4.0`)
+- adds a wrapper for common gems:
+  - looks for a binstub under `./bin/` and executes it (if present)
+  - calls `bundle exec <gem executable>` otherwise
+
+For a full list of *common gems* being wrapped by default please look at the `bundler.plugin.zsh` file.
+
+## Configuration
+
+Please use the exact name of the executable and not the gem name.
+
+### Add additional gems to be wrapped
+
+Add this before the plugin-list in your `.zshrc`:
+```sh
+BUNDLED_COMMANDS=(rubocop)
+plugins=(... bundler ...)
+```
+This will add the wrapper for the `rubocop` gem (i.e. the executable).
+
+
+### Exclude gems from being wrapped
+
+Add this before the plugin-list in your `.zshrc`:
+```sh
+UNBUNDLED_COMMANDS=(foreman spin)
+plugins=(... bundler ...)
+```
+This will exclude the `foreman` and `spin` gems (i.e. their executable) from being wrapped.
+
+## Excluded gems
+
+These gems should not be called with `bundle exec`. Please see [issue #2923](https://github.com/robbyrussell/oh-my-zsh/pull/2923) on GitHub for clarification.
+
+`berks`
+`foreman`
+`mailcatcher`
+`rails`
+`ruby`
+`spin`
diff --git a/modules/bundler/_bundler b/modules/bundler/_bundler
new file mode 100644
index 00000000..ba647ab8
--- /dev/null
+++ b/modules/bundler/_bundler
@@ -0,0 +1,104 @@
+#compdef bundle
+
+local curcontext="$curcontext" state line _gems _opts ret=1
+
+_arguments -C -A "-v" -A "--version" \
+	'(- 1 *)'{-v,--version}'[display version information]' \
+	'1: :->cmds' \
+	'*:: :->args' && ret=0
+
+case $state in
+	cmds)
+		_values "bundle command" \
+			"install[Install the gems specified by the Gemfile or Gemfile.lock]" \
+			"update[Update dependencies to their latest versions]" \
+			"package[Package the .gem files required by your application]" \
+			"exec[Execute a script in the context of the current bundle]" \
+			"config[Specify and read configuration options for bundler]" \
+			"check[Determine whether the requirements for your application are installed]" \
+			"list[Show all of the gems in the current bundle]" \
+			"show[Show the source location of a particular gem in the bundle]" \
+			"outdated[Show all of the outdated gems in the current bundle]" \
+			"console[Start an IRB session in the context of the current bundle]" \
+			"open[Open an installed gem in the editor]" \
+			"viz[Generate a visual representation of your dependencies]" \
+			"init[Generate a simple Gemfile, placed in the current directory]" \
+			"gem[Create a simple gem, suitable for development with bundler]" \
+			"platform[Displays platform compatibility information]" \
+			"clean[Cleans up unused gems in your bundler directory]" \
+			"help[Describe available tasks or one specific task]"
+		ret=0
+		;;
+	args)
+		case $line[1] in
+			help)
+				_values 'commands' \
+                    'install' \
+                    'update' \
+                    'package' \
+                    'exec' \
+                    'config' \
+                    'check' \
+                    'list' \
+                    'show' \
+                    'outdated' \
+                    'console' \
+                    'open' \
+                    'viz' \
+                    'init' \
+                    'gem' \
+                    'platform' \
+                    'help' && ret=0
+				;;
+			install)
+				_arguments \
+					'(--no-color)--no-color[disable colorization in output]' \
+					'(--local)--local[do not attempt to connect to rubygems.org]' \
+					'(--quiet)--quiet[only output warnings and errors]' \
+					'(--gemfile)--gemfile=-[use the specified gemfile instead of Gemfile]:gemfile' \
+					'(--system)--system[install to the system location]' \
+					'(--deployment)--deployment[install using defaults tuned for deployment environments]' \
+					'(--frozen)--frozen[do not allow the Gemfile.lock to be updated after this install]' \
+					'(--path)--path=-[specify a different path than the system default]:path:_files' \
+					'(--binstubs)--binstubs=-[generate bin stubs for bundled gems to ./bin]:directory:_files' \
+					'(--without)--without=-[exclude gems that are part of the specified named group]:groups'
+				ret=0
+				;;
+			exec)
+				_normal && ret=0
+				;;
+			clean)
+				_arguments \
+					'(--force)--force[forces clean even if --path is not set]' \
+					'(--dry-run)--dry-run[only print out changes, do not actually clean gems]' \
+					'(--no-color)--no-color[Disable colorization in output]' \
+					'(--verbose)--verbose[Enable verbose output mode]'
+				ret=0
+				;;
+			outdated)
+				_arguments \
+					'(--pre)--pre[Check for newer pre-release gems]' \
+					'(--source)--source[Check against a specific source]' \
+					'(--local)--local[Do not attempt to fetch gems remotely and use the gem cache instead]' \
+					'(--no-color)--no-color[Disable colorization in output]' \
+					'(--verbose)--verbose[Enable verbose output mode]'
+				ret=0
+				;;
+			(open|show)
+				_gems=( $(bundle show 2> /dev/null | sed -e '/^  \*/!d; s/^  \* \([^ ]*\) .*/\1/') )
+				if [[ $_gems != "" ]]; then
+					_values 'gems' $_gems && ret=0
+				fi
+				;;
+			*)
+				_opts=(  $(bundle help $line[1] | sed -e '/^  \[-/!d; s/^  \[\(-[^=]*\)=.*/\1/') )
+				_opts+=( $(bundle help $line[1] | sed -e '/^  -/!d; s/^  \(-.\), \[\(-[^=]*\)=.*/\1 \2/') )
+				if [[ $_opts != "" ]]; then
+					_values 'options' $_opts && ret=0
+				fi
+				;;
+		esac
+		;;
+esac
+
+return ret
diff --git a/modules/bundler/init.zsh b/modules/bundler/init.zsh
new file mode 100644
index 00000000..c5284dbb
--- /dev/null
+++ b/modules/bundler/init.zsh
@@ -0,0 +1,112 @@
+alias be="bundle exec"
+alias bl="bundle list"
+alias bp="bundle package"
+alias bo="bundle open"
+alias bout="bundle outdated"
+alias bu="bundle update"
+alias bi="bundle_install"
+alias bcn="bundle clean"
+
+bundled_commands=(
+  annotate
+  cap
+  capify
+  cucumber
+  foodcritic
+  guard
+  irb
+  jekyll
+  kitchen
+  knife
+  middleman
+  nanoc
+  pry
+  puma
+  rackup
+  rainbows
+  rake
+  rspec
+  shotgun
+  sidekiq
+  spec
+  spork
+  spring
+  strainer
+  tailor
+  taps
+  thin
+  thor
+  unicorn
+  unicorn_rails
+)
+
+# Remove $UNBUNDLED_COMMANDS from the bundled_commands list
+for cmd in $UNBUNDLED_COMMANDS; do
+  bundled_commands=(${bundled_commands#$cmd});
+done
+
+# Add $BUNDLED_COMMANDS to the bundled_commands list
+for cmd in $BUNDLED_COMMANDS; do
+  bundled_commands+=($cmd);
+done
+
+## Functions
+
+bundle_install() {
+  if _bundler-installed && _within-bundled-project; then
+    local bundler_version=`bundle version | cut -d' ' -f3`
+    if [[ $bundler_version > '1.4.0' || $bundler_version = '1.4.0' ]]; then
+      if [[ "$OSTYPE" = darwin* ]]
+      then
+        local cores_num="$(sysctl -n hw.ncpu)"
+      else
+        local cores_num="$(nproc)"
+      fi
+      bundle install --jobs=$cores_num $@
+    else
+      bundle install $@
+    fi
+  else
+    echo "Can't 'bundle install' outside a bundled project"
+  fi
+}
+
+_bundler-installed() {
+  which bundle > /dev/null 2>&1
+}
+
+_within-bundled-project() {
+  local check_dir="$PWD"
+  while [ "$check_dir" != "/" ]; do
+    [ -f "$check_dir/Gemfile" ] && return
+    check_dir="$(dirname $check_dir)"
+  done
+  false
+}
+
+_binstubbed() {
+  [ -f "./bin/${1}" ]
+}
+
+_run-with-bundler() {
+  if _bundler-installed && _within-bundled-project; then
+    if _binstubbed $1; then
+      ./bin/$@
+    else
+      bundle exec $@
+    fi
+  else
+    $@
+  fi
+}
+
+## Main program
+for cmd in $bundled_commands; do
+  eval "function unbundled_$cmd () { $cmd \$@ }"
+  eval "function bundled_$cmd () { _run-with-bundler $cmd \$@}"
+  alias $cmd=bundled_$cmd
+
+  if which _$cmd > /dev/null 2>&1; then
+    compdef _$cmd bundled_$cmd=$cmd
+  fi
+done