#
# A simple theme that displays relevant, contextual information.
#
# Authors:
#   Sorin Ionescu <sorin.ionescu@gmail.com>
#
# Screenshots:
#   http://i.imgur.com/nBEEZ.png
#

# Load dependencies.
pmodload 'helper'

function prompt_sorin_pwd {
  local pwd="${PWD/#$HOME/~}"

  if [[ "$pwd" == (#m)[/~] ]]; then
    _prompt_sorin_pwd="$MATCH"
    unset MATCH
  else
    _prompt_sorin_pwd="${${${(@j:/:M)${(@s:/:)pwd}##.#?}:h}%/}/${pwd:t}"
  fi
}

function prompt_sorin_precmd {
  setopt LOCAL_OPTIONS
  unsetopt XTRACE KSH_ARRAYS

  # Format PWD.
  prompt_sorin_pwd

  # Get Git repository information.
  if (( $+functions[git-info] )); then
    git-info
  fi
}

function prompt_sorin_setup {
  setopt LOCAL_OPTIONS
  unsetopt XTRACE KSH_ARRAYS
  prompt_opts=(cr percent subst)

  # Load required functions.
  autoload -Uz add-zsh-hook

  # Add hook for calling git-info before each command.
  add-zsh-hook precmd prompt_sorin_precmd

  # Set editor-info parameters.
  zstyle ':prezto:module:editor:info:completing' format '%F{red}...%F{black}'
  zstyle ':prezto:module:editor:info:keymap:primary' format ' %F{red}❯%F{yellow}❯%F{green}❯%F{default}'
  zstyle ':prezto:module:editor:info:keymap:primary:overwrite' format ' %F{red}♺%F{black}'
  zstyle ':prezto:module:editor:info:keymap:alternate' format ' %F{green}❮%F{yellow}❮%F{red}❮%F{default}'

  # Set git-info parameters.
  zstyle ':prezto:module:git:info' verbose 'yes'
  zstyle ':prezto:module:git:info:action' format ':%F{yellow}%s%F{black}'
  zstyle ':prezto:module:git:info:added' format ' %F{green}✚%F{black}'
  zstyle ':prezto:module:git:info:ahead' format ' %F{yellow}⬆%F{black}'
  zstyle ':prezto:module:git:info:behind' format ' %F{yellow}⬇%F{black}'
  zstyle ':prezto:module:git:info:branch' format ':%F{green}%b%F{black}'
  zstyle ':prezto:module:git:info:commit' format ':%F{green}%.7c%F{black}'
  zstyle ':prezto:module:git:info:deleted' format ' %F{red}✖%F{black}'
  zstyle ':prezto:module:git:info:modified' format ' %F{blue}✹%F{black}'
  zstyle ':prezto:module:git:info:position' format ':%F{red}%p%F{black}'
  zstyle ':prezto:module:git:info:renamed' format ' %F{magenta}➜%F{black}'
  zstyle ':prezto:module:git:info:stashed' format ' %F{cyan}⚑%F{black}'
  zstyle ':prezto:module:git:info:unmerged' format ' %F{yellow}═%F{black}'
  zstyle ':prezto:module:git:info:untracked' format ' %F{white}✭%F{black}'
  zstyle ':prezto:module:git:info:keys' format \
    'prompt' ' %F{blue}git%f$(coalesce "%b" "%p" "%c")%s' \
    'rprompt' '%A%B%S%a%d%m%r%U%u'

  # Define prompts.
  PROMPT='%F{cyan}${_prompt_sorin_pwd}%f${git_info:+${(e)git_info[prompt]}}%(!. %B%F{red}#%f%b.)${editor_info[keymap]} '
  RPROMPT='${editor_info[overwrite]}%(?:: %F{red}⏎%f)${VIM:+" %B%F{green}V%f%b"}${git_info[rprompt]}'
  SPROMPT='zsh: correct %F{red}%R%f to %F{green}%r%f [nyae]? '
}

prompt_sorin_setup "$@"