47467a1b0e
I'm not a huge fan of this change, as I've made it known. However, this is semi-recommended by the style guide we've chosen to use and is a more common syntax. Fixes #692.
41 lines
909 B
Text
41 lines
909 B
Text
#
|
|
# Provides for trapping UNIX signals and calling callback functions when a trap
|
|
# is triggered.
|
|
#
|
|
# Authors:
|
|
# Sorin Ionescu <sorin.ionescu@gmail.com>
|
|
#
|
|
|
|
# Adds a function name to a list to be called when a trap is triggered.
|
|
add-zsh-trap() {
|
|
if (( $# < 2 )); then
|
|
print "usage: $0 type function" >&2
|
|
return 1
|
|
fi
|
|
|
|
if [[ -z "$signals[(r)$1]" ]]; then
|
|
print "$0: unknown signal: $1" >&2
|
|
return 1
|
|
fi
|
|
|
|
local trap_functions="TRAP${1}_FUNCTIONS"
|
|
if (( ! ${(P)+trap_functions} )); then
|
|
typeset -gaU "$trap_functions"
|
|
fi
|
|
eval "$trap_functions+="$2""
|
|
|
|
if (( ! $+functions[TRAP${1}] )); then
|
|
eval "
|
|
TRAP${1}() {
|
|
for trap_function in \"\$TRAP${1}_FUNCTIONS[@]\"; do
|
|
if (( \$+functions[\$trap_function] )); then
|
|
\"\$trap_function\" \"\$1\"
|
|
fi
|
|
done
|
|
return \$(( 128 + \$1 ))
|
|
}
|
|
"
|
|
fi
|
|
}
|
|
|
|
add-zsh-trap "$@"
|